dsscsy	JMP clsynt
dsscom	JSR gtintA
	LDA &2A
	STA &54
	LDA &2B
	STA &55
	LDA #0
	STA &6F
	JSR getchB
	DEC &1B
	CMP #13
	BEQ dssntc
	JSR chkcma
	JSR getchB
	CMP #'C'
	BNE dsscsy
	DEC &6F
dssntc	JSR cendB
	LDA #14
	JSR &FFEE
dsslop	BIT &FF
	BPL nodes
	LDA #15
	JSR &FFEE
	RTS
nodes	LDY #2
gtbtlp	LDA (&54),Y
	STA &56,Y
	DEY
	BPL gtbtlp
	LDA &55
	JSR phex
	LDA &54
	JSR phex
	LDA #32
	JSR &FFEE
	JSR &FFEE
	LDA &56
	TAX
	LDA offset,X
	STA &59
	LDA mode,X
	BPL dsncmd
	BIT &6F
	BMI dsncmd
	LDA #&F
dsncmd	AND #127
	ASL A
	TAX
	LDA dtble,X
	STA &5A
	LDA dtble+1,X
	STA &5B
	JMP (&5A)
dtble	DW immed
	DW imp
	DW acc
	DW abs
	DW absX
	DW absY
	DW zp
	DW zpX
	DW zpY
	DW indX
	DW indY
	DW indABS
	DW rel
	DW indABX
	DW ind
	DW equb
	DW bbrtp
immed	LDA #2
	JSR pdta
	JSR pmnem
	JSR pflmss
	ASC "#&"
	BRK
	LDA &57
	JSR phex
	JMP add2
imp	LDA #1
	JSR pdta
	JSR pmnem
	JMP add1
acc	LDA #1
	JSR pdta
	JSR pmnem
	LDA #'A'
	JSR &FFEE
	JMP add1
abs	LDA #3
	JSR pdta
	JSR pmnem
	JSR pabs
	JMP add3
absX	LDA #3
	JSR pdta
	JSR pmnem
	JSR pabs
	JSR pflmss
	ASC ",X"
	BRK
	JMP add3
absY	LDA #3
	JSR pdta
	JSR pmnem
	JSR pabs
	JSR pflmss
	ASC ",Y"
	BRK
	JMP add3
ind	LDA #2
	JSR pdta
	JSR pmnem
	LDA #'('
	JSR &FFEE
	JSR pzp
	LDA #')'
	JSR &FFEE
	JMP add2
zp	LDA #2
	JSR pdta
	JSR pmnem
	JSR pzp
	JMP add2
zpX	LDA #2
	JSR pdta
	JSR pmnem
	JSR pzp
	JSR pflmss
	ASC ",X"
	BRK
	JMP add2
zpY	LDA #2
	JSR pdta
	JSR pmnem
	JSR pzp
	JSR pflmss
	ASC ",Y"
	BRK
	JMP add2
indX	LDA #2
	JSR pdta 
	JSR pmnem
	LDA #'('
	JSR &FFEE
	JSR pzp
	JSR pflmss
	ASC ",X)"
	BRK
	JMP add2
indY	LDA #2
	JSR pdta
	JSR pmnem
	LDA #'('
	JSR &FFEE
	JSR pzp
	JSR pflmss
	ASC "),Y"
	BRK
	JMP add2
indABS	LDA #3
	JSR pdta
	JSR pmnem
	LDA #'('
	JSR &FFEE
	JSR pabs
	LDA #')'
	JSR &FFEE
	JMP add3
indABX	LDA #3
	JSR pdta
	JSR pmnem
	LDA #'('
	JSR &FFEE
	JSR pabs
	JSR pflmss
	ASC ",X)"
	BRK
	JMP add3
rel	LDA #2
	JSR pdta
	JSR pmnem
	LDA #0
	STA &58
	LDA &57
	BPL nodec
	DEC &58
nodec	SEC
	ADC &54
	STA &57
	LDA &55
	ADC &58
	STA &58
	INC &57
	BNE nopge
	INC &58
nopge	JSR pabs
	JMP add2
equb	LDA #1
	JSR pdta
	LDA #22
	STA &5B
	JSR tab
	JSR pflmss
	ASC "EQUB &"
	BRK
	LDA &56
	JSR phex
	JMP add1
bbrtp	LDA #2
	JSR pdta
	JSR pmnem
	LDA &56
	LSR
	LSR
	LSR
	LSR
	AND #7
	ORA #&30
	JSR &FFEE
	LDA #','
	JSR &FFEE
	JSR pzp
	JMP add2


pdta	STA &5A
	LDY #0
pdtalp	LDA &56,Y
	JSR phex
	LDA #' '
	JSR &FFEE
	INY
	CPY &5A
	BNE pdtalp
	LDA #16
	STA &5B
	JSR tab
	LDY #0
pdtlp2	LDA &56,Y
	CMP #' '
	BCC pdtdot
	CMP #127
	BCS pdtdot
	JMP pdtov
pdtdot	LDA #'.'
pdtov	JSR &FFEE
	INY
	CPY &5A
	BNE pdtlp2
	RTS
tab	LDA #134
	JSR &FFF4
	LDA #' '
tablp	CPX &5B
	BEQ etab
	JSR &FFEE
	INX
	JMP tablp
etab	RTS
pmnem	LDA #22
	STA &5B
	JSR tab
	LDA &59
	ASL A
	CLC
	ADC &59
	TAX
	LDA text,X
	JSR &FFEE
	INX
	LDA text,X
	JSR &FFEE
	INX
	LDA text,X
	JSR &FFEE
	LDA #' '
	JMP &FFEE
add1	LDA #1
	BNE add
add2	LDA #2
	BNE add
add3	LDA #3
add	CLC
	ADC &54
	STA &54
	LDA #0
	ADC &55
	STA &55
	JSR &FFE7
	JMP dsslop
pabs	LDA #'&'
	JSR &FFEE
	LDA &58
	JSR phex
	LDA &57
	JMP phex
pzp	LDA #'&'
	JSR &FFEE
	LDA &57
	JMP phex
mode
	DFB 1		;BYTE0
	DFB 9
	DFB 15
	DFB 15
	DFB 134
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 2
	DFB 15
	DFB 128
	DFB 3
	DFB 3
	DFB 144
	
	DFB 12		;BYTE 10
	DFB 10
	DFB 142
	DFB 15
	DFB 134
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 130
	DFB 15
	DFB 128
	DFB 4
	DFB 4
	DFB 144
	
	DFB 3		;BYTE 20
	DFB 9
	DFB 15
	DFB 15
	DFB 6
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 2
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144

	DFB 12		;BYTE 30
	DFB 10
	DFB 142
	DFB 15
	DFB 135
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 130
	DFB 15
	DFB 132
	DFB 4
	DFB 4
	DFB 144
	     	
	DFB 1		;BYTE 40
	DFB 9
	DFB 15
	DFB 15
	DFB 15
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 2
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144

	DFB 12		;BYTE 50
	DFB 10
	DFB 142
	DFB 15
	DFB 15
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 129
	DFB 15
	DFB 15
	DFB 4
	DFB 4
	DFB 144
	
	DFB 1		;BYTE 60
	DFB 9
	DFB 15
	DFB 15
	DFB 134
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 2
	DFB 15
	DFB 11
	DFB 3
	DFB 3
	DFB 144
	
	DFB 12		;BYTE 70
	DFB 10
	DFB 142
	DFB 15
	DFB 135
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 129
	DFB 15
	DFB 141
	DFB 4
	DFB 4
	DFB 144
	
	DFB 140		;BYTE 80
	DFB 9
	DFB 15
	DFB 15
	DFB 6
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 128
	DFB 1
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144
	
	DFB 12		;BYTE 90
	DFB 10
	DFB 142
	DFB 15
	DFB 7
	DFB 7
	DFB 8
	DFB 144
	DFB 1
	DFB 5
	DFB 1
	DFB 15
	DFB 131
	DFB 4
	DFB 132
	DFB 144

	DFB 0		;BYTE A0
	DFB 9
	DFB 0
	DFB 15
	DFB 6
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 1
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144

	DFB 12		;BYTE B0
	DFB 10
	DFB 142
	DFB 15
	DFB 7
	DFB 7
	DFB 8
	DFB 144
	DFB 1
	DFB 5
	DFB 1
	DFB 15
	DFB 4
	DFB 4
	DFB 5
	DFB 144
	
	DFB 0		;BYTE C0
	DFB 9
	DFB 15
	DFB 15
	DFB 6
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 1
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144
	
	DFB 12		;BYTE D0
	DFB 10
	DFB 142
	DFB 15
	DFB 15
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 129
	DFB 15
	DFB 15
	DFB 4
	DFB 4
	DFB 144

	DFB 0		;BYTE E0
	DFB 9
	DFB 15
	DFB 15
	DFB 6
	DFB 6
	DFB 6
	DFB 144
	DFB 1
	DFB 0
	DFB 1
	DFB 15
	DFB 3
	DFB 3
	DFB 3
	DFB 144
	
	DFB 12		;BYTE F0
	DFB 10
	DFB 142
	DFB 15
	DFB 15
	DFB 7
	DFB 7
	DFB 144
	DFB 1
	DFB 5
	DFB 129
	DFB 15
	DFB 15
	DFB 4
	DFB 4
	DFB 144
	
offset	DFB 1		;BYTE 00
	DFB &24
	DFB &FF
	DFB &FF
	DFB &39
	DFB &24
	DFB &29
	DFB &3C
	DFB &C
	DFB &24
	DFB &29
	DFB &FF
	DFB &39
	DFB &24
	DFB &29
	DFB &3A
	
	DFB &1F 	;BYTE 10
	DFB &24
	DFB &24
	DFB &FF
	DFB &3B
	DFB &24
	DFB &29
	DFB &3C
	DFB &2
	DFB &24
	DFB &2E
	DFB &FF
	DFB &3B
	DFB &24
	DFB &29
	DFB &3A

	DFB &33		;BYTE 20
	DFB &22
	DFB &FF
	DFB &FF
	DFB &31
	DFB &22
	DFB &2B
	DFB &3C
	DFB &E
	DFB &22
	DFB &2B
	DFB &FF
	DFB &31
	DFB &22
	DFB &2B
	DFB &3A
	
	DFB &1D		;BYTE 30
	DFB &22
	DFB &22
	DFB &FF
	DFB &31
	DFB &22
	DFB &2B
	DFB &3C
	DFB &11
	DFB &22
	DFB &2D
	DFB &FF
	DFB &31
	DFB &22
	DFB &2B
	DFB &3A
	
	DFB &F 		;BYTE 40
	DFB &23
	DFB &FF
	DFB &FF
	DFB &FF
	DFB &23
	DFB &2A
	DFB &3C
	DFB &B
	DFB &23
	DFB &2A
	DFB &FF
	DFB &32
	DFB &23
	DFB &2A
	DFB &3A
	
	DFB &20		;BYTE 50
	DFB &23
	DFB &23
	DFB &FF
	DFB &FF
	DFB &23
	DFB &2A
	DFB &3C
	DFB &4
	DFB &23
	DFB &3D
	DFB &FF
	DFB &FF
	DFB &23
	DFB &2A
	DFB &3A
	
	DFB &10 	;BYTE 60
	DFB &25
	DFB &FF
	DFB &FF
	DFB &44
	DFB &25
	DFB &2C
	DFB &3C
	DFB &D
	DFB &25
	DFB &2C
	DFB &FF
	DFB &32
	DFB &25
	DFB &2C
	DFB &3A
	
	DFB &21 	;BYTE 70
	DFB &25
	DFB &25
	DFB &FF
	DFB &44
	DFB &25
	DFB &2C
	DFB &3C
	DFB &13
	DFB &25
	DFB &3F
	DFB &FF
	DFB &32
	DFB &25
	DFB &2C
	DFB &3A
	
	DFB &43 	;BYTE 80
	DFB &36
	DFB &FF
	DFB &FF
	DFB &38
	DFB &36
	DFB &37
	DFB &42
	DFB &7
	DFB &31
	DFB &17
	DFB &FF
	DFB &38
	DFB &36
	DFB &37
	DFB &41
	
	DFB &1A 	;BYTE 90
	DFB &36
	DFB &36
	DFB &FF
	DFB &38
	DFB &36
	DFB &37
	DFB &42
	DFB &19
	DFB &36
	DFB &18
	DFB &FF
	DFB &44
	DFB &36
	DFB &44
	DFB &41
	
	DFB &35 	;BYTE A0
	DFB &27
	DFB &34
	DFB &FF
	DFB &35
	DFB &27
	DFB &34
	DFB &42
	DFB &15
	DFB &27
	DFB &14
	DFB &FF
	DFB &35
	DFB &27
	DFB &34
	DFB &41
	
	DFB &1B 	;BYTE B0
	DFB &27
	DFB &27
	DFB &FF
	DFB &35
	DFB &27
	DFB &34
	DFB &42
	DFB &5
	DFB &27
	DFB &16
	DFB &FF
	DFB &35
	DFB &27
	DFB &34
	DFB &41
	
	DFB &30 	;BYTE C0
	DFB &26
	DFB &FF
	DFB &FF
	DFB &30
	DFB &26
	DFB &2D
	DFB &42
	DFB &9
	DFB &26
	DFB &6
	DFB &F
	DFB &30
	DFB &26
	DFB &2D
	DFB &41
	
	DFB &1E 	;BYTE D0
	DFB &26
	DFB &26
	DFB &FF
	DFB &FF
	DFB &26
	DFB &2D
	DFB &42
	DFB &3
	DFB &26
	DFB &3E
	DFB &FF
	DFB &FF
	DFB &26
	DFB &2D
	DFB &41
	
	DFB &2F 	;BYTE E0
	DFB &28
	DFB &FF
	DFB &FF
	DFB &2F
	DFB &28
	DFB &2E
	DFB &42
	DFB &8
	DFB &28
	DFB &A
	DFB &FF
	DFB &2F
	DFB &28
	DFB &2E
	DFB &41
	
	DFB &1C 	;BYTE F0
	DFB &28
	DFB &28
	DFB &FF
	DFB &FF
	DFB &28
	DFB &2E
	DFB &42
	DFB &12
	DFB &28
	DFB &40
	DFB &FF
	DFB &FF
	DFB &28
	DFB &2E
	DFB &41
	
text	ASC "XXX"
	ASC "BRK"
	ASC "CLC"
	ASC "CLD"
	ASC "CLI"
	ASC "CLV"
	ASC "DEX"
	ASC "DEY"
	ASC "INX"
	ASC "INY"
	ASC "NOP"
	ASC "PHA"
	ASC "PHP"
	ASC "PLA"
	ASC "PLP"
	ASC "RTI"
	ASC "RTS"
	ASC "SEC"
	ASC "SED"
	ASC "SEI"
	ASC "TAX"
	ASC "TAY"
	ASC "TSX"
	ASC "TXA"
	ASC "TXS"
	ASC "TYA"
	ASC "BCC"
	ASC "BCS"
	ASC "BEQ"
	ASC "BMI"
	ASC "BNE"
	ASC "BPL"
	ASC "BVC"
	ASC "BVS"
	ASC "AND"
	ASC "EOR"
	ASC "ORA"
	ASC "ADC"
	ASC "CMP"
	ASC "LDA"
	ASC "SBC"
	ASC "ASL"
	ASC "LSR"
	ASC "ROL"
	ASC "ROR"
	ASC "DEC"
	ASC "INC"
	ASC "CPX"
	ASC "CPY"
	ASC "BIT"
	ASC "JMP"
	ASC "JSR"
	ASC "LDX"
	ASC "LDY"
	ASC "STA"
	ASC "STX"
	ASC "STY"
	ASC "TSB"
	ASC "BBR"
	ASC "TRB"
	ASC "RMB"
	ASC "PHY"
	ASC "PHX"
	ASC "PLY"
	ASC "PLX"
	ASC "BBS"
	ASC "SMB"
	ASC "BRA"
	ASC "STZ"
	ASC "XXX"

mix	JSR gtintA
	LDA &2A
	STA &60
	JSR chkcma
	JSR gtintB
	LDA &2A
	STA &61
	JSR cendB
	LDY #fillc1
	LDA &60
	STA (&52),Y
	INY
	LDA &61
	STA (&52),Y
	RTS
free	JSR cendA
	JSR &FFE7
	JSR pflmss
	ASC "Free memory =&"
	BRK
	JSR fremem
	LDA &2A
	STA &54
	LDA &2B
	JSR phex
	LDA &54
	JSR phex
	JSR pflmss
	STR " Bytes"
	ASC "Program size=&"
	BRK
	LDA top
	SEC
	SBC #0
	STA &54
	LDA top+1
	SBC page
	JSR phex
	LDA &54
	JSR phex
	JSR pflmss
	STR " Bytes"
	ASC "Next free location=&"
	BRK
	LDA frmem+1
	JSR phex
	LDA frmem
	JSR phex
	JSR &FFE7
	JSR pflmss
	ASC "PAGE=&"
	BRK
	LDA page
	JSR phex
	LDA #0
	JSR phex
	JSR pflmss
	ASC "   LOMEM=&"
	BRK
	LDA lomem+1
	JSR phex
	LDA lomem
	JSR phex
	JSR &FFE7
	JSR pflmss
	ASC "TOP =&"
	BRK
	LDA top+1
	JSR phex
	LDA top
	JSR phex
	JSR pflmss
	ASC "   HIMEM=&"
	BRK
	LDA himem+1
	JSR phex
	LDA himem
	JSR phex
	JSR &FFE7
	JMP &FFE7
fkey	JSR tsteA
	BCC fkyall
	JSR gtintB
	LDA &2A
	AND #15
	PHA
	JSR cendB
	PLA
	TAY
	JMP fkey2
fkyall	JSR cendB		
	LDY #0
fkeyml	TYA
	PHA
	JSR fkey2
	PLA
	TAY
	INY
	CPY #16
	BNE fkeyml
	RTS
fkey2	JSR pflmss
	ASC "*KEY "
	BRK
	TYA
	PHA
	STA &2A
	LDA #0
	STA &2B
	JSR plnum0
	LDA #32
	JSR &FFEE
	LDA #0
	LDX #1
	JSR &FFF4
	CPX #3
	BNE fkey2b
	LDX #0
showlp	LDA showm,X
	STA &100,X
	INX
	CMP #32
	BNE showlp
	PLA
	CMP #10
	BCC shwone
	PHA
	LDA #&31
	STA &100,X
	INX
	PLA
	SEC
	SBC #10
shwone	ORA #&30
	STA &100,X
	INX
	LDA #13
	STA &100,X
	LDX #0
	LDY #1
	JMP &FFF7

showm	ASC "SHOW "

fkey2b	PLA
	TAY
	LDX &B00,Y
	STX &67
	LDA &B10
	STA &66
	LDX #&F
fkeyl1	LDA &B00,X
	CMP &67
	BCC fkeyo1
	BEQ fkeyo1
	CMP &66
	BCS fkeyo1
	STA &66
fkeyo1	DEX
	BPL fkeyl1
	LDA #&22
	JSR &FFEE
	LDX &67
	INC &66
fkeyl2	INX
	CPX &66
	BCC fkeyo2
	LDA #&22
	JSR &FFEE
	JMP &FFE7
fkeyo2	LDA &B00,X
	BPL fkeyo3
	PHA
	JSR pflmss
	ASC "||!"
	BRK
	PLA
fkeyo3	AND #&7F
	CMP #&20
	BCC fkeyo7
	CMP #&22
	BEQ fkeyo4
	CMP #&7C
	BEQ fkeyo5
	CMP #&7F
	BCC fkeyo6
	JSR pflmss
	ASC "||?"
	BRK
	JMP fkeyl2
fkeyo4	JSR fkycd
	JSR &FFEE
	JMP fkeyl2
fkeyo5	JSR &FFEE
fkeyo6	JSR &FFEE
	JMP fkeyl2
fkeyo7	JSR fkycd
	ORA #&40
	BNE fkeyo6
fkycd	PHA
	LDA #'||'
	JSR &FFEE
	PLA
	RTS

pdecnm	STX &2A
	STY &2B
	JMP plnum0

envl	JSR tsteA
	BCC envall
	JSR gtintB
	JSR cendB
	DEC &2A
	LDA &2A
	AND #15
	STA &56
	ASL
	ASL
	ASL
	ASL
	STA &54
	JMP envlp

envall	JSR cendB
	LDA #0
	STA &54
	STA &56
envmlp	LDX &56
	INX
	JSR envlp
	LDA &54
	CLC
	ADC #16
	STA &54
	INC &56
	LDA &56
	CMP #16
	BNE envmlp
	JMP &FFE7

envlp	JSR pflmss
	ASC "ENVELOPE "
	BRK
	LDX &56
	INX
	LDY #0
	JSR pdecnm
	LDX &54
envlp2	LDA #&2C
	JSR &FFEE
	LDA &8C0,X
	LDY #0
	STX &55
	TAX
	JSR pdecnm
	LDX &55
	INX
	TXA
	SEC
	SBC &54
	CMP #13
	BNE envlp2
	JMP &FFE7
dform	JSR tstfs1
	JSR gtintA
	LDA &2A
	AND #3
	STA &54
	JSR chkcma
	JSR gtintB
	LDA &2A
	CMP #40
	BEQ dszok
	CMP #80
	BEQ dszok
	CBRK
	DFB 52
	ASC "Bad disc size"
	BRK
dszok	STA &55
	JSR tsteB
	BCC clext
	JSR chkcma
	JSR getchB
	CMP #'E'
	BEQ stext
	CBRK
	DFB 53
	ASC "Bad catalogue type"
	BRK
stext	LDA #1
	JMP extok
clext	LDA #0
extok	STA &56
	LDA #0
	STA &57
	JSR cendB
	JSR pflmss
	DFB 13
	ASC "Go? (Y/N)"
	BRK
	JSR &FFE0
	AND #223
	CMP #'Y'
	BEQ form
	LDA #'N'
	JSR &FFEE
	JMP &FFE7
form	JSR &FFEE
	JSR &FFE7
	LDA &54
	STA &6E0
	LDA #0
	STA &6E1
	LDA #&6
	STA &6E2
	LDA #&FF
	STA &6E3
	STA &6E4
	LDA #5
	STA &6E5
	LDA #&63
	STA &6E6
	LDA &57
	STA &6E7
	LDA #21
	STA &6E8
	LDA #&2A
	STA &6E9
	LDA #0
	STA &6EA
	LDA #16
	STA &6EB
	LDY #&FF
frmlp1 INY
	LDA fmdata,Y
	STA &600,Y
	CPY #40
	BNE frmlp1
frmlp2	LDA &FF
	BPL frmnes
	JMP &FFE7
frmnes	LDY #0
frmlp3	LDA &57
	STA &600,Y
	LDA &602,Y
	SEC
	SBC #1
	BCS frmov
	LDA #9
frmov	STA &602,Y
	INY
	INY
	INY
	INY
	CPY #40
	BNE frmlp3
	LDA &57
	STA &6E7
	JSR phex
	LDA #' '
	JSR &FFEE
	JSR &FFEE
	LDX #&E0
	LDY #6
	LDA #127
	JSR &FFF1
	INC &57
	LDA &57
	CMP &55
	BNE frmlp2
	JSR &FFE7
	LDA #&20
	STA &59
	LDA #0
	STA &58
	LDX #4
	LDY #0
frmlp4	STA (&58),Y
	INY
	BNE frmlp4
	INC &59
	DEX
	BNE frmlp4
	LDA #8
	STA &2105
	STA &2305
	LDA #2
	STA &210F
	STA &230F
	STA &230D
	LDA #&A1
	STA &200F
	STA &220F
	LDA #&21
	LDY #6
frmlp5	STA &2008,Y
	STA &2208,Y
	DEY
	BPL frmlp5
	LDA &55
	CMP #80
	BEQ frm8
	LDA #1
	STA &2106
	LDA #&90
	STA &2107
	LDA #&C8
	STA &210C
	STA &2307
	JMP frmtr
frm8	LDA #3
	STA &2106
	LDA #&20
	STA &2107
	LDA #&90
	STA &210D
	STA &2307
	LDA #1
	STA &2306
	LDA #16
	STA &210E
frmtr	LDY #0
frmlp6	LDA frmhd,Y
	STA &600,Y
	INY
	CPY #11
	BNE frmlp6
	LDA &56
	BNE frmdo
	LDA #&22
	STA &609
	LDA #0
	STA &2105
	LDY #8
frmlp7	STA &2000,Y
	STA &2100,Y
	INY
	CPY #16
	BNE frmlp7
frmdo	LDX #0
	LDY #6
	LDA #127
	JMP &FFF1
frmhd	DFB 255
	DW &2000
	DW &FFFF
	DFB 3
	DFB &4B
	BRK
	BRK
	DFB &24
fmdata	BRK
	BRK
	DFB 1
	DFB 1
	BRK
	BRK
	DFB 2
	DFB 1
	BRK
	BRK
	DFB 3
	DFB 1
	BRK
	BRK
	DFB 4
	DFB 1
	BRK
	BRK
	DFB 5
	DFB 1
	BRK
	BRK
	DFB 6
	DFB 1
	BRK
	BRK
	DFB 7
	DFB 1
	BRK
	BRK
	DFB 8
	DFB 1
	BRK
	BRK
	DFB 9
	DFB 1
	BRK
	BRK
	BRK
	DFB 1

noscct	CBRK
	DFB 54
	ASC "No second catalogue"
	BRK
dswap	JSR tstfs1
	JSR tsteA
	BCC dswpnd
	JSR gtintB
	LDA &2A
	AND #3
	ORA #&30
	PHA
	LDY #0
swplp1	LDA drive,Y
	STA &600,Y
	INY
	CPY #10
	BNE swplp1
	PLA
	STA &607
	LDX #0
	LDY #6
	JSR &FFF7
dswpnd	JSR cendB
CLLSWP	LDY #0
swplp2	LDA swpld,Y
	STA &600,Y
	INY
	CPY #50
	BNE swplp2
	LDX #33
	LDY #6
	LDA #&40
	JSR &FFCE
	CMP #0
	BEQ noscct
	TAY
	LDA #0
	JSR &FFCE
	LDX #0
	JSR swpcl
	LDX #11
	JSR swpcl
	LDX #22
swpcl	LDY #6
	LDA #127
	JMP &FFF1
swpld	DFB 255
	DW &7800
	DW &FFFF
	DFB 3
	DFB &53
	BRK
	BRK
	DFB &24
	BRK

	DFB 255
	DW &7A00
	DW &FFFF
	DFB 3
	DFB &4B
	BRK
	BRK
	DFB &22
	BRK

	DFB 255
	DW &7800
	DW &FFFF
	DFB 3
	DFB &4B
	BRK
	DFB 2
	DFB &22
	BRK

swpnm	STR "!.!!!!!!!"
drive	STR "*DRIVE  "

cat	JSR tstfs2
	CMP #4
	BEQ catdsc
	JSR cendA
	JMP cat2
catdsc	LDY #0
catlp	LDA swpnm,Y
	STA &600,Y
	INY
	CPY #30
	BNE catlp
	JSR tsteA
	BCC ctnodr
	JSR gtintB
	LDA &2A
	AND #3
	ORA #&30
	STA &611
	LDX #10
	LDY #6
	JSR &FFF7
ctnodr	JSR cendB
	JSR cat2
	LDX #0
	LDY #6
	LDA #&40
	JSR &FFCE
	CMP #0
	BNE seccat
	RTS
seccat	TAY
	LDA #0
	JSR &FFCE
	JSR pflmss
	ASC "Press a key for more..."
	BRK
	JSR &FFE0
	JSR &FFE7
	JSR CLLSWP
	JSR cat2
	JSR CLLSWP
	RTS
cat2	LDA #&2E
	STA &650
	LDA #13
	STA &651
	LDX #&50
	LDY #6
	JMP &FFF7

dverfy	JSR gtintA
	LDA &2A
	AND #3
	STA &54
	JSR getchB
	CMP #13
	BEQ dvstnd
	CMP #&2C
	BNE csynt
	JSR gtintB
	LDA &2A
	STA &55
	JSR chkcma
	JSR gtintB
	LDA &2A
	STA &56
	JSR cendB
	JSR tstfs1
	LDY #&FF
dvdrl2	INY
	LDA drive,Y
	STA &600,Y
	CMP #13
	BNE dvdrl2
	LDA &54
	ORA #&30
	STA &607
	LDX #0
	LDY #6
	JSR &FFF7
	LDA &55
	JMP dvgo
csynt	JMP comerr
dvstnd	LDA #0
	STA &56
	DEC &1B
	JSR cendB
	JSR tstfs1
	LDY #&FF
dvdrl	INY
	LDA drive,Y
	STA &600,Y
	CMP #13
	BNE dvdrl
	LDA &54
	ORA #&30
	STA &607
	LDX #0
	LDY #6
	JSR &FFF7
	LDX #&60
	LDY #0
	LDA #&7E
	JSR &FFF1
	LDA &61
	CMP #&90
	BNE dvn4
	LDA &62
	CMP #1
	BNE dvsze
	LDA #40
	JMP dvgo
dvsze	CBRK
	DFB 52
	ASC "Bad disc size"
	BRK
dvn4	CMP #&20
	BNE dvsze
	LDA &62
	CMP #3
	BNE dvsze
	LDA #80
dvgo	STA &55
	LDY #0
dvlp1	LDA dvblk,Y
	STA &600,Y
	INY
	CPY #11
	BNE dvlp1
	LDA &54
	STA &600
dvlp2	BIT &FF
	BPL ndvesc
	JMP &FFE7
ndvesc	LDA &56
	STA &607
	JSR phex
	LDA #32
	JSR &FFEE
	JSR &FFEE
	LDX #0
	LDY #6
	LDA #127
	JSR &FFF1
	LDA &60A
	BNE dverr
	INC &56
	LDA &56
	CMP &55
	BNE dvlp2
	JMP &FFE7
dverr	JSR &FFE7
	JSR pflmss
	ASC "Verify error"
	BRK
	RTS
dvblk	BRK
	DW &FFFF
	DW &FFFF
	DFB 3
	DFB &5F
	BRK
	BRK
	DFB &2A
	BRK
tstfs1	JSR tstfs2
	CMP #4
	BEQ etstfs
	CBRK
	DFB 55
	ASC "Wrong filing system"
	BRK
tstfs2	LDY #0
	LDA #0
	LDX #&60
	JSR &FFDA
etstfs	RTS

view	JSR testdi
	JSR gtstrA
	JSR cendB
	LDA #&40
	LDX #0
	LDY #6
	JSR &FFCE
	CMP #0
	BNE viewok
	JMP CLFLBK
viewok	STA &54
	JSR viewgt
	CMP #13
	BEQ vwlp1
	JSR vwcls
nbasfl	CBRK
	DFB 56
	ASC "Not BASIC file"
	BRK
vwlp1	JSR &FFE3
	BIT &FF
	BPL vwnoes
vwend	JSR &FFE7
	JMP vwcls
vwnoes	LDA #0
	STA &1E
	STA &55
	JSR viewgt
	BMI vwend
	STA &2B
	JSR viewgt
	STA &2A
	JSR viewgt
	JSR plnum5
	LDA #32
	JSR &FFEE
vwlp2	JSR viewgt
	CMP #13
	BEQ vwlp1
	CMP #&22
	BNE vwn22
	LDA &55
	EOR #1
	STA &55
	LDA #&22
vwn22	LDX &55
	BEQ vwtok
	JSR &FFEE
	JMP vwlp2
vwtok	CMP #&8D
	BNE vwtok2
	JSR viewgt
	ASL A
	ASL A
	PHA
	AND #&C0
	STA &58
	JSR viewgt
	EOR &58
	STA &59
	PLA
	ASL A
	ASL A
	STA &58
	JSR viewgt
	EOR &58
	TAY
	LDX &59
	JSR pdecnm
	JMP vwlp2
vwtok2	LDX #ptoken
	JSR clbROM
	JMP vwlp2
viewgt	LDY &54
	JSR &FFD7
	BCS vweof
	RTS
vweof	JSR vwcls
	CBRK
	DFB 223
	ASC "EOF"
	BRK
vwcls	LDA #0
	LDY &54
	JMP &FFCE

tsteA	JSR getchA
	JMP tsteAB
tsteB	JSR getchB
tsteAB	DEC &1B
	CMP #':'
	BEQ tsteok
	CMP #&8B
	BEQ tsteok
	CMP #13
	BEQ tsteok
	SEC
	RTS
tsteok	CLC
	RTS

	CHN "EXT2C"